# Fix SanSanDisk Ultra Fit bug
# On reboot monunted as usb1 instead usb2
#
# First check mount point
# Reset usb power if required
# Recheck mount point
# Start containers if required

:while (([/disk get [find slot=usb1] mounted] || [/disk get [find slot=usb2] mounted]) != true) do={
    :log info "No disks mounted";
    :delay delay-time=3s
}

:if ([/disk get [find slot=usb1] mounted]) do={
    :log info "usb1 mounted ... unmounting...";
    :system routerboard usb power-reset duration=1s
    :delay delay-time=3s
}

:while ([/disk get [find slot=usb2] mounted] != true) do={
    :log info "usb2 not mounted";
    :system routerboard usb power-reset duration=1s
    :delay delay-time=3s
}

:log info "usb2 mounted";

:local iAdguardProxyContainer [/container/find start-on-boot=yes && interface=veth11-adguardProxy];

:if ([/container/get $iAdguardProxyContainer status] = "stopped") do={
    :log info "Starting container (veth = $[/container/get $iAdguardProxyContainer value-name=interface]) ...";
    :container/start $iAdguardProxyContainer
    :delay delay-time=1s
}

:foreach iContainer in=[/container/find start-on-boot=yes] do={
    :if ([/container/get $iContainer value-name=status] = "stopped") do={
        :log info "Starting container (veth = $[/container/get $iContainer value-name=interface]) ...";
        :container/start $iContainer
        :delay delay-time=1s
    }
}

/container/config/set ram-high=640M