/system script
add name=voltmonitor policy=\
    ftp,reboot,read,write,policy,test,winbox,password,sniff source="#set lowvol\
    talarm to desired alarm voltage in tenths of a volt. 125 = 12.5v\r\
    \n:global lowvoltalarm 210\r\
    \n:global highvolt\r\
    \n:global lowvolt\r\
    \n:global starttime\r\
    \n:global hivolttime\r\
    \n:global lovolttime\r\
    \n:global vh\r\
    \n:local thisbox [/system identity get name]\r\
    \n:global voltage [/system health get voltage]\r\
    \n:local thistime [/system clock get time]\r\
    \n:local thisdate [/system clock get date]\r\
    \n:local thishour [:pick \$thistime 0 2]\r\
    \n:local emessage (\$thisbox . \" voltage is \" . [:pick \$voltage 0 2] . \
    \".\" . [:pick \$voltage 2 3])\r\
    \n:if ([:len \$lowvolt] < 1) do={:set lowvolt 999; :set highvolt 0}\r\
    \n# set your email address in the next line\r\
    \n:if (\$voltage <= \$lowvoltalarm) do={/tool e-mail send to=\"voltagemonit\
    or@mydomain\" subject=\"\$thisbox low voltage\" body=\$emessage}\r\
    \n:if (\$voltage > \$highvolt) do={:set highvolt \$voltage; :set hivolttime\
    \_(\$thistime . \" \" . \$thisdate)}\r\
    \n:if (\$voltage < \$lowvolt) do={:set lowvolt \$voltage; :set lovolttime (\
    \$thistime . \" \" . \$thisdate)}\r\
    \n:if ([:len \$vh] > 0) do={:set vh ([:toarray \$voltage] + \$vh)} else={:s\
    et vh [:toarray \$voltage]}\r\
    \n:if ([:len \$starttime] < 1) do={:set starttime (\$thistime . \" \" . \$t\
    hisdate)}\r\
    \n:if (\$thishour = \"23\") do={:execute voltreport}"

add name=voltreport policy=\
    ftp,reboot,read,write,policy,test,winbox,password,sniff source=":global hig\
    hvolt\r\
    \n:global lowvolt\r\
    \n:global hivolttime\r\
    \n:global lovolttime\r\
    \n:global starttime\r\
    \n:global vh\r\
    \n:local tvolt\r\
    \n:local thisbox [/system identity get name]\r\
    \n:local thisdate [/system clock get date]\r\
    \n:local thishour\r\
    \n:local emessage \"Daily voltage report for \$thisbox on \$thisdate\\n\\n\
    \"\r\
    \n:if ([:len \$vh] > 0) do={\r\
    \n    :for x from=0 to=([:len \$vh]-1) step=1 do={\r\
    \n        :set tvolt [:tostr [:pick \$vh \$x]]\r\
    \n        :set thishour [:tostr (23 - \$x)]\r\
    \n        :while ([:len \$thishour] < 2) do={:set thishour (\"0\" . \$thish\
    our)}\r\
    \n        :set emessage (\$emessage . \$thishour . \":00 = \" . [:pick \$tv\
    olt 0 2] . \".\" . [:pick \$tvolt 2 3] .  \"\\n\")\r\
    \n    }\r\
    \n    :set emessage (\$emessage . \"\\nSince voltmonitor started on \" . \$\
    starttime . \"\\n\")\r\
    \n    :set tvolt [:tostr \$highvolt]\r\
    \n    :set emessage (\$emessage . \"Maximum = \" . [:pick \$tvolt 0 2] . \"\
    .\" . [:pick \$tvolt 2 3] . \"v at \" . \$hivolttime . \"\\n\")\r\
    \n    :set tvolt [:tostr \$lowvolt]\r\
    \n    :set emessage (\$emessage . \"Minimum = \" . [:pick \$tvolt 0 2] . \"\
    .\" . [:pick \$tvolt 2 3] . \"v at \" . \$lovolttime . \"\\n\")\r\
    \n# set email address in next line\r\
    \n    /tool e-mail send to=\"voltagemonitor@mydomain\" subject=\"\$thisbo\
    x Voltage Report\" body=\$emessage\r\
    \n}\r\
    \n# remark out the next line for testing to avoid resetting the voltage arr\
    ay\r\
    \n:set vh"

/system scheduler
add comment="" disabled=no interval=1h name=schedule1 on-event=voltmonitor \
    policy=reboot,read,write,policy,test,password,sniff start-date=aug/27/2009 \
    start-time=08:00:00

Daily voltage report for Myboard1 on sep/10/2009

23:00 = 23.8
22:00 = 23.9
21:00 = 23.9
20:00 = 23.9
19:00 = 23.9
18:00 = 23.9
17:00 = 23.9
16:00 = 23.9
15:00 = 23.9
14:00 = 23.9
13:00 = 24.0
12:00 = 24.0
11:00 = 24.1
10:00 = 24.1
09:00 = 24.2
08:00 = 24.3
07:00 = 24.5
06:00 = 25.8
05:00 = 25.8
04:00 = 25.7
03:00 = 25.7
02:00 = 25.6
01:00 = 25.5
00:00 = 27.0

Since voltmonitor started on 20:00:00 aug/30/2009
Maximum = 27.0v at 05:00:00 aug/31/2009
Minimum = 21.0v at 09:00:00 sep/09/2009